Model 2: The Abakus Clock

Date:2017-08-19

Design Decisions

  • 32 ticks/sec, generated from main crystal (11.0592 MHz)
  • timeup clock with simple counters, no structures, no timezone
  • optional: uptime counter
  • optional: led.1 blinking 1/sec
  • multitasker
  • new: a battery backed real time clock is connected via i2c
  • new: start time is read from RTC
  • new: shift register drives LEDs as display

Description

The code included below is a complete, working example, tested on an atmega644p controller. The syntax for the includes is such that amforth-shell.py will upload the programm and resolve all #include file directives.

This clock is derived from the Minimal Clock by adding a geek display (Abakus Display) and a battery backed RTC.

../../_images/i_abakus_display.jpg

I2C RTC (PCF8583)

#include i2c_rtc_pcf8583.fs

Abakus Display

Obviously, we need to define the pin connected to the shift register, and load the words to transfer data to the shift register(s)

\ abakus display
PORTD 2 portpin: sr_latch
PORTD 3 portpin: sr_clock
PORTD 4 portpin: sr_data

#include shiftregister.fs
../../_images/i_model2_1.jpg

Controller Board and display

../../_images/i_model2_3.jpg

Prototype Display handrouted :-)

The Code

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
\ 2017-08-16  main-02-abakus.fs
\ Author: Erich Wälde
\ License: this code is explizitly placed in the public domain
\
\ include syntax for upload with amforth-shell.py
\
\     11.059200 MHz main crystal
\     timer/counter1
\     32 ticks/second
\
\ minimal clock
\ plus i2c, i2c RTC (pcf8583)
\      display: shift registers (74x595) and LEDs
\
#include builds.frt
#include erase.frt
#include dot-base.frt
#include imove.frt
#include bitnames.frt
#include marker.frt
#include environment-q.frt
#include dot-res.frt
#include avr-values.frt
#include is.frt
#include dumper.frt
#include interrupts.frt
\ these definitions are resolved by amforth-shell.py as needed
\ include atmega644p.fs

#include flags.frt
#include 2variable.frt
#include 2constant.frt
#include 2-fetch.frt
#include 2-store.frt
#include m-star-slash.frt
#include quotations.frt
#include avr-defers.frt
#include defers.frt

marker --start--

\ --- ports, pins, masks

PORTB 2 portpin: led.0
PORTB 3 portpin: led.1
PORTB 4 portpin: led.2
PORTB 5 portpin: led.3

PORTC 0 portpin: i2c_scl
PORTC 1 portpin: i2c_sda

\ abakus display
PORTD 2 portpin: sr_latch
PORTD 3 portpin: sr_clock
PORTD 4 portpin: sr_data

\ --- famous includes and other words
: ms   ( n -- )       0 ?do pause 1ms loop ;
: u0.r ( u n -- )     >r 0 <# r> 0 ?do # loop #> type ;
: odd?  ( x -- t/f )  $0001 and 0= 0= ;
: even? ( x -- t/f )  $0001 and 0= ;

\ --- driver: status leds
#include leds.fs

\ --- driver: i2c rtc clock
: bcd>dec  ( n.bcd -- n.dec )
  $10 /mod  #10 * + ;
: dec>bcd  ( n.dec -- n.bcd )
  #100 mod  #10 /mod  $10 * + ;

#include i2c-twi-master.frt
#include i2c.frt
#include i2c-detect.frt
: +i2c  ( -- )
  i2c_scl pin_pullup_on
  i2c_sda pin_pullup_on
  0  \ prescaler
  #6 \ bit rate --- 400kHz @ 11.0592 MHz
  i2c.init
;

: i2c.scan
  base @ hex
  $79 $7 do
    i i2c.ping? if i 3 .r then
  loop
  base !
  cr
;
$50 constant i2c_addr_rtc
#include i2c_rtc_pcf8583.fs


\ --- master clock
\ --- timeup
#include timeup_v0.0.fs
                                        \ tu.counts -- fields available as:
                                        \   tick sec min hour day month year
                                        \ last_day_of_month ( year month -- last_day )
                                        \ timeup.init
                                        \ timeup
                                        \ tu.upd.limits ( Y m -- )

\ --- uptime
2variable uptime
: .uptime  ( -- )  uptime 2@  decimal ud. [char] s emit ;
: ++uptime ( -- )  1.  uptime 2@  d+  uptime 2! ;

\ --- timer1 clock tick
\ 32 ticks/sec
\ timer_1_ overflow
\ clock source main crystal/256
#include clock_tick1_main.fs
                                        \ +ticks
                                        \ tick.over?  ( -- t/f )
                                        \ tick.over!
                                        \ half.second.over?  ( -- 0|1|2 )
: clock.set ( Y m d H M S -- )
  sec ! min ! hour !
  1- day !
  over over
  1- month ! year !
  ( Y m ) tu.upd.limits
;
: clock.get ( -- S M H d m Y )
  sec @ min @ hour @
  day @ 1+ month @ 1+ year @
;
: clock.dot ( S M H d m Y -- )
  #4 u0.r [char] - emit #2 u0.r [char] - emit #2 u0.r  [char] _  emit
  #2 u0.r [char] : emit #2 u0.r [char] : emit #2 u0.r
;
: clock.show ( -- )
  clock.get
  clock.dot
;

: .date
  year  @    4 u0.r
  month @ 1+ 2 u0.r
  day   @ 1+ 2 u0.r
;
: .time
  hour @ 2 u0.r [char] : emit
  min  @ 2 u0.r [char] : emit
  sec  @ 2 u0.r
;

: hwclock>clock ( -- )
  rtc.get    \ --
     year  !
  1- month !
  1- day   !
     hour  !
     min   !
     sec   !
  drop \ 1/100 secs
  year @   month @ 1+  tu.upd.limits
;
: clock>hwclock ( -- )
  year @   month @ 1+  day @ 1+
  hour @   min   @     sec @
  tick @ #100 ticks/sec m*/
  ( Y m d H M S S/100 ) rtc.set
;

#include shiftregister.fs
#include abakus.fs
: clock.display.abakus.time   ( -- )
  hour @  #10 /mod swap
  min  @  #10 /mod swap
  sec  @  #10 /mod swap
  6 type.abakus
;

\ --- multitasker
#include multitask.frt
: +tasks  multi ;
: -tasks  single ;


\ --- timeup jobs ---------------------------
: job.tick
;
: job.sec
  ++uptime
  clock.display.abakus.time
;
: job.min
;
: job.hour  ;
: job.day   ;
: job.month
  \ update length of month in tu.limits
  year @  month @ 1+  tu.upd.limits
;
: job.year
              \ update YYYY in eeprom of rtc
  \ year @  rtc.set.year
;

create Jobs
  ' job.tick ,
  ' job.sec , ' job.min ,   ' job.hour ,
  ' job.day , ' job.month , ' job.year ,

variable jobCount
: jobCount++
  jobCount @
  6 < if
    1 jobCount +!
  then
;

\ --- task 2 --------------------------------
: run-masterclock
  ['] tx-poll to emit \ add emit to run-masterclock
  begin

    tick.over? if
      tick.over!
      1 tick +!
      job.tick
    then

    half.second.over?
    dup 0<> if
      dup odd? if       \ half second
        led.1 off
      else              \ second
        led.1 on
        timeup
        0 tick !
        1 jobCount !
      then
    then
    drop

    \ run one job per loop, not all at once
    jobCount @
    bv tu.flags fset?
    if
      jobCount @ dup
      Jobs + @i execute
      bv tu.flags fclr
    then
    jobCount++

    pause
  again
;
$40 $40 0 task: task-masterclock \ create task space
: start-masterclock
  task-masterclock tib>tcb
  activate
  \ words after this line are run in new task
  run-masterclock
;
: starttasker
  task-masterclock task-init            \ create TCB in RAM
  start-masterclock                     \ activate tasks job

  onlytask                              \ make cmd loop task-1
  task-masterclock tib>tcb alsotask     \ start task-2
  multi                                 \ activate multitasking
;

\ --- main ----------------------------------
: init
  +leds leds-intro
  #2017 1 1 0 0 0 clock.set
  0. uptime 2!
  +ticks
  timeup.init
  +i2c
  i2c_addr_rtc i2c.ping? if
    hwclock>clock
  else
    #2017 1 1 0 0 0 clock.set
  then
  +sr
;
: run
  init
  starttasker
;
: run-turnkey
  applturnkey
  init
  starttasker
;
\ ' run-turnkey to turnkey

: .d ( -- )
  decimal
  .uptime         space space
  clock.show      space
  tick            @ . space
  ct.ticks.follow @ .
  cr
;